Nombres, sinonimos, genero y numero de los objetos

Género y número

Todo objeto debe tener obligatoriamente un nombre usando la palabra clave nombre, y éste nombre debe tener delante el género y el número MS:, MP:, FS:, FP: como sigue.

Prefijo MS: = Masculino singular

nombre MS:zapato

Prefijo MP: = Masculino plural

nombre MP:pantalones

Prefijo FS:= Femenino singular

nombre FS:pelota

Prefijo FP: = Femenino plural

nombre FP:zapatillas

La ventaja de ponerle género y número a los nombres es que los mensajes de resultado de las acciones, el listado de objetos y el inventario van acorde con este dato.

include system/default

object Main:MainBase
    def start
        Estado.jugador = McAventura
        #jugador.accion(Mirar)
    end
endobject

/**
* El objeto jugador
*/
object McAventura:Personaje dentro:Habitacion
    nombre MS:Mc Aventura
    def alMirar: "Eres Mc Aventura, el protagonista de esta historia."
endobject

/**
* Localidades
*/
object Habitacion:Localidad
    nombre MS:Habitación
    def alMirar: "Estás en tu habitación, cálida y soleada, de donde parten tus primeros recuerdos."
endobject

/**
* Objetos en la Habitación
*/
object Mechero dentro:Habitacion
    nombre MS:mechero
    def alMirar: "Es un mechero de color rojo."
endobject

object Pantalones dentro:Habitacion
    nombre MP:pantalones
    def alMirar: "Son tus pantalones de hacer deporte."
endobject

object Pelota dentro:Habitacion
    nombre FS:pelota
    def alMirar: "Es una pelota azul muy bonita."
endobject

object Zapatillas dentro:Habitacion
    nombre FP:zapatillas
    def alMirar: "Son tus zapatillas de correr."
endobject

Si probamos este ejemplo:

Habitación
Estás en tu habitación, cálida y soleada, de donde parten tus primeros recuerdos.

Salidas posibles: ninguna.
Puedes ver un mechero, unos pantalones, una pelota y unas zapatillas.
>> coger zapatillas
Cogidas.

>> coger todo
Coges el mechero, los pantalones y la pelota.

>> i
Llevas:
 un mechero
 unos pantalones
 una pelota
 unas zapatillas

• En el listado de objetos de la localidad y el inventario se listan los objetos anteponiéndoles el pronombre correcto "un", "una", "unos", "unas".
• En el resultado de la acción coger zapatillas, el mensaje "Cogidas" tiene en cuenta que es femenino plural.
• Y Coger todo enumera los objetos cogidos anteponiéndoles el pronombre correcto "el", "la", "los", "las".

Nombres propios

Cuando un objeto es un personaje y queremos referirnos a el por su nombre, necesitamos especificar que es un nombre propio. Para ello utilizaremos un flag llamado "propio". El concepto de flag se verá más adelante, en Nuevo concepto, flags y variables

Nombres compuestos

Los nombres de los objetos pueden estar formados por varias palabras. El único problema es que si el nombre es compuesto, para referirnos al objeto, es necesario introducir todo el nombre y no una parte de él.

Si cambiamos el nombre del objeto pelota a "pelota azul" así:

object Pelota dentro:Habitacion
    nombre FS:pelota azul
    def alMirar: "Es una pelota azul muy bonita."
endobject

Solo podremos referirnos al objeto con todas sus palabras. Si no ponemos el nombre completo falla.

>>mirar pelota
No veo eso que dices.

>>coger pelota azul
Es una pelota azul muy bonita.

Entonces, ¿qué podemos hacer para que podamos usar "pelota" y "pelota azul" como nombres? Usando sinónimos.

Sinónimos

Es posible dar más de un nombre a un objeto, añadiéndole sinónimos con la palabra clave sinonimos y añadiendo nuevos nombres separados por comas. Cada nombre puede tener su género y número delante.

Esto añade un nuevos sinónimo al objeto pelota, cada uno con su genero y número correcto.

sinonimos FS:pelota, MS:balón, MS:balón azul

Aunque podríamos ahorrarnos repetir el genero y número delante de cada sinónimo, ya que se usará el último, quedando el objeto así:

object Pelota dentro:Habitacion
    nombre FS:pelota azul
    sinonimos pelota, MS:balón, balón azul
    def alMirar: "Es una pelota azul muy bonita."
endobject

Ahora ya podemos probar a utilizar todos estos nuevos nombres, el sistema los reconoce y los pinta acorde con su genero y número. E incluso recuerda el último nombre utilizado, por lo que podemos usar verbos sin objeto como dejalo en vez de dejar balon.

>> coger pelota
Cogida.

>> dejala
Dejas la pelota por aquí.

>> coger balon azul
Cogido.

>> dejalo
Dejas el balón azul por aquí.

>> coger balon
Cogido.

>> dejar pelota
Dejas la pelota por aquí.

Más sinónimos: atajos

Si un objeto va a tener muchos nombres compuestos, es posible definir varios nombres de golpe separados por una barra |. Y si uno o varios nombres son opcionales, pueden acabar en una interrogación ?

El mismo ejemplo anterior de la pelota azul quedaría ahora así:

object Pelota dentro:Habitacion
    nombre FS:pelota azul
    sinonimos pelota, MS:balón azul?
    def alMirar: "Es una pelota azul muy bonita."
endobject

Resumen

Hemos aprendido que todo objeto debe tener un nombre y, opcionalmente, sinónimos. El sistema utilizará el nombre cuando liste los objetos, pero permite al jugador utilizar este nombre o cualquiera de sus sinónimos para referirse a un objeto dentro de una acción.

Tanto los nombres y los sinónimos deben tener un género y un número delante: MS:, MP:, FS: o FP: (F= Femenino, M=Masculino, S=Singular, P=Plural)

Los nombres y sinónimos pueden ser compuestos y contener más de una palabra. Además, algunas de estas palabras pueden ser opcionales si acaban en ?. Y se pueden definir varios nombres a la vez si se separan con una barra |.